我這個(gè)是根據(jù)個(gè)人習(xí)慣做的筆記,一般常用的我就不記了,記一些愛(ài)忘記的!!!

10年積累的成都做網(wǎng)站、成都網(wǎng)站制作經(jīng)驗(yàn)，可以快速應(yīng)對(duì)客戶對(duì)網(wǎng)站的新想法和需求。提供各種問(wèn)題對(duì)應(yīng)的解決方案。讓選擇我們的客戶得到更好、更有力的網(wǎng)絡(luò)服務(wù)。我雖然不認(rèn)識(shí)你，你也不認(rèn)識(shí)我。但先網(wǎng)站制作后付款的網(wǎng)站建設(shè)流程，更有馬龍免費(fèi)網(wǎng)站建設(shè)讓你可以放心的選擇與我們合作。

sed -[nerif] '行號(hào),行號(hào) action/str/str/action' file

(/,@,#都是前面所說(shuō)的地址定界符)

sed 's@@@' file
sed 's///' file
sed 's###' file

這三種方式都行

sed命令的語(yǔ)法格式：

sed的命令格式： sed [option] 'sed command'filename

sed的腳本格式：sed [option] -f 'sed script'filename

sed命令的選項(xiàng)(option)：

-n ：只打印模式匹配的行

-e ：直接在命令行模式上進(jìn)行sed動(dòng)作編輯，此為默認(rèn)選項(xiàng)

-f ：將sed的動(dòng)作寫(xiě)在一個(gè)文件內(nèi)，用–f filename 執(zhí)行filename內(nèi)的sed動(dòng)作

-r ：支持?jǐn)U展表達(dá)式

-i ：直接修改文件內(nèi)容

在此的/bash/為匹配字段,匹配bash,然后把root改為hello,然后打印出來(lái)

[root@hxy working]# sed -n '/bash/s/root/hello/p'  /etc/passwd
hello:x:0:0:root:/root:/bin/bash

在

提取IP的命令

ifconfig|grep -B1 "inet addr" |grep -v "\-\-" |sed -n -e 'N;s/\(eth[0-9]\).*\n.*addr:\(.*\)/\1 \2/p'|awk '{print $1,$2}'

解釋下,我之前都不知道\1 \2是怎么來(lái)的,在網(wǎng)上查了老半天才明白;

在sed中 sed 's/\(str1\)str\(str2\)/\1 \2/p' 這里的str1就代表了\1 str2就代表了\2

這樣的域是用括號(hào)括起來(lái)的,后面才能知道的

sed變量替換變量

eval sed 's/$a/$b/' filename
sed "s/$a/$b/" filename
sed 's/'$a'/'$b'/' filename
sed s/$a/$b/ filename

#正常的用單引號(hào)也是無(wú)效的
[root@hxy working]# echo "hello world"|sed 's/$a/$b/'
hello world
root@hxy working]# echo "hello world"|eval sed 's/$a/$b/'
nihao world
#如果是加在前面就是無(wú)效的
[root@hxy working]# eval echo "hello world"|sed 's/$a/$b/'
hello world
[root@hxy working]# echo "hello world"|sed "s/$a/$b/"
nihao world
[root@hxy working]# echo "hello world"|sed 's/'$a'/'$b'/'
nihao world
[root@hxy working]# echo "hello world"|sed s/$a/$b/
nihao world

一個(gè)有關(guān)sed的一個(gè)面試題

##1）、處理以下文件內(nèi)容,將域名取出并進(jìn)行計(jì)數(shù)排序,如處理:  
http://www.baidu.com/index.<a target="_blank"  >html</a>  
http://www.baidu.com/1.html  
http://post.baidu.com/index.html  
http://mp3.baidu.com/index.html  
http://www.baidu.com/3.html  
http://post.baidu.com/2.html  
得到如下結(jié)果:  
域名的出現(xiàn)的次數(shù) 域名  
3 www.baidu.com  
2 post.baidu.com  
1 mp3.baidu.com  
[root@hxy working]# cat file | sed -e ' s/http:\/\///' -e ' s/\/.*//' | sort | uniq -c | sort -rn  
3 www.baidu.com  
2 post.baidu.com  
1 mp3.baidu.com  
[root@hxy working]# awk -F/ '{print $3}' file |sort -r|uniq -c|awk '{print $1"\t",$2}'  
3 www.baidu.com  
2 post.baidu.com  
1 mp3.baidu.com

sed的用法很多,我在網(wǎng)上copy了一篇文章雖然感覺(jué)用到的很少,但是留著可能會(huì)用到

ed（文件）命令的一些用法
 
文本間隔：
--------
 # 在每一行后面增加一空行
 sed G
 # 將原來(lái)的所有空行刪除并在每一行后面增加一空行。
 # 這樣在輸出的文本中每一行后面將有且只有一空行。
 sed '/^$/d;G'
 # 在每一行后面增加兩行空行
 sed 'G;G'
 # 將第一個(gè)腳本所產(chǎn)生的所有空行刪除（即刪除所有偶數(shù)行）
 sed 'n;d'
 # 在匹配式樣“regex”的行之前插入一空行
 sed '/regex/{x;p;x;}'
 # 在匹配式樣“regex”的行之后插入一空行
 sed '/regex/G'
 # 在匹配式樣“regex”的行之前和之后各插入一空行
 sed '/regex/{x;p;x;G;}'
編號(hào)：
--------
 # 為文件中的每一行進(jìn)行編號(hào)（簡(jiǎn)單的左對(duì)齊方式）。這里使用了“制表符”
 # （tab，見(jiàn)本文末尾關(guān)于'\t'的用法的描述）而不是空格來(lái)對(duì)齊邊緣。
 sed = filename | sed 'N;s/\n/\t/'
 # 對(duì)文件中的所有行編號(hào)（行號(hào)在左，文字右端對(duì)齊）。
 sed = filename | sed 'N; s/^/     /; s/ *\(.\{6,\}\)\n/\1  /'
 # 對(duì)文件中的所有行編號(hào)，但只顯示非空白行的行號(hào)。
 sed '/./=' filename | sed '/./N; s/\n/ /'
 # 計(jì)算行數(shù) （模擬 "wc -l"）
 sed -n '$='
文本轉(zhuǎn)換和替代：
--------
 # Unix環(huán)境：轉(zhuǎn)換DOS的新行符（CR/LF）為Unix格式。
 sed 's/.$//'                     # 假設(shè)所有行以CR/LF結(jié)束
 sed 's/^M$//'                    # 在bash/tcsh中，將按Ctrl-M改為按Ctrl-V
 sed 's/\x0D$//'                  # ssed、gsed 3.02.80，及更高版本
 # Unix環(huán)境：轉(zhuǎn)換Unix的新行符（LF）為DOS格式。
 sed "s/$/`echo -e \\\r`/"        # 在ksh下所使用的命令
 sed 's/$'"/`echo \\\r`/"         # 在bash下所使用的命令
 sed "s/$/`echo \\\r`/"           # 在zsh下所使用的命令
 sed 's/$/\r/'                    # gsed 3.02.80 及更高版本
 # DOS環(huán)境：轉(zhuǎn)換Unix新行符（LF）為DOS格式。
 sed "s/$//"                      # 方法 1
 sed -n p                         # 方法 2
 # DOS環(huán)境：轉(zhuǎn)換DOS新行符（CR/LF）為Unix格式。
 # 下面的腳本只對(duì)UnxUtils sed 4.0.7 及更高版本有效。要識(shí)別UnxUtils版本的
 #  sed可以通過(guò)其特有的“--text”選項(xiàng)。你可以使用幫助選項(xiàng)（“--help”）看
 # 其中有無(wú)一個(gè)“--text”項(xiàng)以此來(lái)判斷所使用的是否是UnxUtils版本。其它DOS
 # 版本的的sed則無(wú)法進(jìn)行這一轉(zhuǎn)換。但可以用“tr”來(lái)實(shí)現(xiàn)這一轉(zhuǎn)換。
 sed "s/\r//" infile >outfile     # UnxUtils sed v4.0.7 或更高版本
 tr -d \r <infile >outfile        # GNU tr 1.22 或更高版本
 # 將每一行前導(dǎo)的“空白字符”（空格，制表符）刪除
 # 使之左對(duì)齊
 sed 's/^[ \t]*//'                # 見(jiàn)本文末尾關(guān)于'\t'用法的描述
 # 將每一行拖尾的“空白字符”（空格，制表符）刪除
 sed 's/[ \t]*$//'                # 見(jiàn)本文末尾關(guān)于'\t'用法的描述
 # 將每一行中的前導(dǎo)和拖尾的空白字符刪除
 sed 's/^[ \t]*//;s/[ \t]*$//'
 # 在每一行開(kāi)頭處插入5個(gè)空格（使全文向右移動(dòng)5個(gè)字符的位置）
 sed 's/^/     /'
 # 以79個(gè)字符為寬度，將所有文本右對(duì)齊
 sed -e :a -e 's/^.\{1,78\}$/ &/;ta'  # 78個(gè)字符外加最后的一個(gè)空格
 # 以79個(gè)字符為寬度，使所有文本居中。在方法1中，為了讓文本居中每一行的前
 # 頭和后頭都填充了空格。 在方法2中，在居中文本的過(guò)程中只在文本的前面填充
 # 空格，并且最終這些空格將有一半會(huì)被刪除。此外每一行的后頭并未填充空格。
 sed  -e :a -e 's/^.\{1,77\}$/ & /;ta'                     # 方法1
 sed  -e :a -e 's/^.\{1,77\}$/ &/;ta' -e 's/\( *\)\1/\1/'  # 方法2
 # 在每一行中查找字串“foo”，并將找到的“foo”替換為“bar”
 sed 's/foo/bar/'                 # 只替換每一行中的第一個(gè)“foo”字串
 sed 's/foo/bar/4'                # 只替換每一行中的第四個(gè)“foo”字串
 sed 's/foo/bar/g'                # 將每一行中的所有“foo”都換成“bar”
 sed 's/\(.*\)foo\(.*foo\)/\1bar\2/' # 替換倒數(shù)第二個(gè)“foo”
 sed 's/\(.*\)foo/\1bar/'            # 替換最后一個(gè)“foo”
 # 只在行中出現(xiàn)字串“baz”的情況下將“foo”替換成“bar”
 sed '/baz/s/foo/bar/g'
 # 將“foo”替換成“bar”，并且只在行中未出現(xiàn)字串“baz”的情況下替換
 sed '/baz/!s/foo/bar/g'
 # 不管是“scarlet”“ruby”還是“puce”，一律換成“red”
 sed 's/scarlet/red/g;s/ruby/red/g;s/puce/red/g'  #對(duì)多數(shù)的sed都有效
 gsed 's/scarlet\|ruby\|puce/red/g'               # 只對(duì)GNU sed有效
 # 倒置所有行，第一行成為最后一行，依次類推（模擬“tac”）。
 # 由于某些原因，使用下面命令時(shí)HHsed v1.5會(huì)將文件中的空行刪除
 sed '1!G;h;$!d'               # 方法1
 sed -n '1!G;h;$p'             # 方法2
 # 將行中的字符逆序排列，第一個(gè)字成為最后一字，……（模擬“rev”）
 sed '/\n/!G;s/\(.\)\(.*\n\)/&\2\1/;//D;s/.//'
 # 將每?jī)尚羞B接成一行（類似“paste”）
 sed '$!N;s/\n/ /'
 # 如果當(dāng)前行以反斜杠“\”結(jié)束，則將下一行并到當(dāng)前行末尾
 # 并去掉原來(lái)行尾的反斜杠
 sed -e :a -e '/\\$/N; s/\\\n//; ta'
 # 如果當(dāng)前行以等號(hào)開(kāi)頭，將當(dāng)前行并到上一行末尾
 # 并以單個(gè)空格代替原來(lái)行頭的“=”
 sed -e :a -e '$!N;s/\n=/ /;ta' -e 'P;D'
 # 為數(shù)字字串增加逗號(hào)分隔符號(hào)，將“1234567”改為“1,234,567”
 gsed ':a;s/\B[0-9]\{3\}\>/,&/;ta'                     # GNU sed
 sed -e :a -e 's/\(.*[0-9]\)\([0-9]\{3\}\)/\1,\2/;ta'  # 其他sed
 # 為帶有小數(shù)點(diǎn)和負(fù)號(hào)的數(shù)值增加逗號(hào)分隔符（GNU sed）
 gsed -r ':a;s/(^|[^0-9.])([0-9]+)([0-9]{3})/\1\2,\3/g;ta'
 # 在每5行后增加一空白行 （在第5，10，15，20，等行后增加一空白行）
 gsed '0~5G'                      # 只對(duì)GNU sed有效
 sed 'n;n;n;n;G;'                 # 其他sed
選擇性地顯示特定行：
--------
 # 顯示文件中的前10行 （模擬“head”的行為）
 sed 10q
 # 顯示文件中的第一行 （模擬“head -1”命令）
 sed q
 # 顯示文件中的最后10行 （模擬“tail”）
 sed -e :a -e '$q;N;11,$D;ba'
 # 顯示文件中的最后2行（模擬“tail -2”命令）
 sed '$!N;$!D'
 # 顯示文件中的最后一行（模擬“tail -1”）
 sed '$!d'                        # 方法1
 sed -n '$p'                      # 方法2
 # 顯示文件中的倒數(shù)第二行
 sed -e '$!{h;d;}' -e x              # 當(dāng)文件中只有一行時(shí)，輸入空行
 sed -e '1{$q;}' -e '$!{h;d;}' -e x  # 當(dāng)文件中只有一行時(shí)，顯示該行
 sed -e '1{$d;}' -e '$!{h;d;}' -e x  # 當(dāng)文件中只有一行時(shí)，不輸出
 # 只顯示匹配正則表達(dá)式的行（模擬“grep”）
 sed -n '/regexp/p'               # 方法1
 sed '/regexp/!d'                 # 方法2
 # 只顯示“不”匹配正則表達(dá)式的行（模擬“grep -v”）
 sed -n '/regexp/!p'              # 方法1，與前面的命令相對(duì)應(yīng)
 sed '/regexp/d'                  # 方法2，類似的語(yǔ)法
 # 查找“regexp”并將匹配行的上一行顯示出來(lái)，但并不顯示匹配行
 sed -n '/regexp/{g;1!p;};h'
 # 查找“regexp”并將匹配行的下一行顯示出來(lái)，但并不顯示匹配行
 sed -n '/regexp/{n;p;}'
 # 顯示包含“regexp”的行及其前后行，并在第一行之前加上“regexp”所
 # 在行的行號(hào) （類似“grep -A1 -B1”）
 sed -n -e '/regexp/{=;x;1!p;g;$!N;p;D;}' -e h
 # 顯示包含“AAA”、“BBB”或“CCC”的行（任意次序）
 sed '/AAA/!d; /BBB/!d; /CCC/!d'  # 字串的次序不影響結(jié)果
 # 顯示包含“AAA”、“BBB”和“CCC”的行（固定次序）
 sed '/AAA.*BBB.*CCC/!d'
 # 顯示包含“AAA”“BBB”或“CCC”的行 （模擬“egrep”）
 sed -e '/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d    # 多數(shù)sed
 gsed '/AAA\|BBB\|CCC/!d'                        # 對(duì)GNU sed有效
 # 顯示包含“AAA”的段落 （段落間以空行分隔）
 # HHsed v1.5 必須在“x;”后加入“G;”，接下來(lái)的3個(gè)腳本都是這樣
 sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;'
 # 顯示包含“AAA”“BBB”和“CCC”三個(gè)字串的段落 （任意次序）
 sed -e '/./{H;$!d;}' -e 'x;/AAA/!d;/BBB/!d;/CCC/!d'
 # 顯示包含“AAA”、“BBB”、“CCC”三者中任一字串的段落 （任意次序）
 sed -e '/./{H;$!d;}' -e 'x;/AAA/b' -e '/BBB/b' -e '/CCC/b' -e d
 gsed '/./{H;$!d;};x;/AAA\|BBB\|CCC/b;d'         # 只對(duì)GNU sed有效
 # 顯示包含65個(gè)或以上字符的行
 sed -n '/^.\{65\}/p'
 # 顯示包含65個(gè)以下字符的行
 sed -n '/^.\{65\}/!p'            # 方法1，與上面的腳本相對(duì)應(yīng)
 sed '/^.\{65\}/d'                # 方法2，更簡(jiǎn)便一點(diǎn)的方法
 # 顯示部分文本——從包含正則表達(dá)式的行開(kāi)始到最后一行結(jié)束
 sed -n '/regexp/,$p'
 # 顯示部分文本——指定行號(hào)范圍（從第8至第12行，含8和12行）
 sed -n '8,12p'                   # 方法1
 sed '8,12!d'                     # 方法2
 # 顯示第52行
 sed -n '52p'                     # 方法1
 sed '52!d'                       # 方法2
 sed '52q;d'                      # 方法3, 處理大文件時(shí)更有效率
 # 從第3行開(kāi)始，每7行顯示一次   
 gsed -n '3~7p'                   # 只對(duì)GNU sed有效
 sed -n '3,${p;n;n;n;n;n;n;}'     # 其他sed
 # 顯示兩個(gè)正則表達(dá)式之間的文本（包含）
 sed -n '/Iowa/,/Montana/p'       # 區(qū)分大小寫(xiě)方式
選擇性地刪除特定行：
--------
 # 顯示通篇文檔，除了兩個(gè)正則表達(dá)式之間的內(nèi)容
 sed '/Iowa/,/Montana/d'
 # 刪除文件中相鄰的重復(fù)行（模擬“uniq”）
 # 只保留重復(fù)行中的第一行，其他行刪除
 sed '$!N; /^\(.*\)\n\1$/!P; D'
 # 刪除文件中的重復(fù)行，不管有無(wú)相鄰。注意hold space所能支持的緩存
 # 大小，或者使用GNU sed。
 sed -n 'G; s/\n/&&/; /^\([ -~]*\n\).*\n\1/d; s/\n//; h; P'
 # 刪除除重復(fù)行外的所有行（模擬“uniq -d”）
 sed '$!N; s/^\(.*\)\n\1$/\1/; t; D'
 # 刪除文件中開(kāi)頭的10行
 sed '1,10d'
 # 刪除文件中的最后一行
 sed '$d'
 # 刪除文件中的最后兩行
 sed 'N;$!P;$!D;$d'
 # 刪除文件中的最后10行
 sed -e :a -e '$d;N;2,10ba' -e 'P;D'   # 方法1
 sed -n -e :a -e '1,10!{P;N;D;};N;ba'  # 方法2
 # 刪除8的倍數(shù)行
 gsed '0~8d'                           # 只對(duì)GNU sed有效
 sed 'n;n;n;n;n;n;n;d;'                # 其他sed
 # 刪除匹配式樣的行
 sed '/pattern/d'                      # 刪除含pattern的行。當(dāng)然pattern
                                       # 可以換成任何有效的正則表達(dá)式
 # 刪除文件中的所有空行（與“grep '.' ”效果相同）
 sed '/^$/d'                           # 方法1
 sed '/./!d'                           # 方法2
 # 只保留多個(gè)相鄰空行的第一行。并且刪除文件頂部和尾部的空行。
 # （模擬“cat -s”）
 sed '/./,/^$/!d'        #方法1，刪除文件頂部的空行，允許尾部保留一空行
 sed '/^$/N;/\n$/D'      #方法2，允許頂部保留一空行，尾部不留空行
 # 只保留多個(gè)相鄰空行的前兩行。
 sed '/^$/N;/\n$/N;//D'
 # 刪除文件頂部的所有空行
 sed '/./,$!d'
 # 刪除文件尾部的所有空行
 sed -e :a -e '/^\n*$/{$d;N;ba' -e '}'  # 對(duì)所有sed有效
 sed -e :a -e '/^\n*$/N;/\n$/ba'        # 同上，但只對(duì) gsed 3.02.*有效
 # 刪除每個(gè)段落的最后一行
 sed -n '/^$/{p;h;};/./{x;/./p;}'
特殊應(yīng)用：
--------
 # 移除手冊(cè)頁(yè)（man page）中的nroff標(biāo)記。在Unix System V或bash shell下使
 # 用'echo'命令時(shí)可能需要加上 -e 選項(xiàng)。
 sed "s/.`echo \\\b`//g"    # 外層的雙括號(hào)是必須的（Unix環(huán)境）
 sed 's/.^H//g'             # 在bash或tcsh中, 按 Ctrl-V 再按 Ctrl-H
 sed 's/.\x08//g'           # sed 1.5，GNU sed，ssed所使用的十六進(jìn)制的表示方法
 # 提取新聞組或 e-mail 的郵件頭
 sed '/^$/q'                # 刪除第一行空行后的所有內(nèi)容
 # 提取新聞組或 e-mail 的正文部分
 sed '1,/^$/d'              # 刪除第一行空行之前的所有內(nèi)容
 # 從郵件頭提取“Subject”（標(biāo)題欄字段），并移除開(kāi)頭的“Subject:”字樣
 sed '/^Subject: */!d; s///;q'
 # 從郵件頭獲得回復(fù)地址
 sed '/^Reply-To:/q; /^From:/h; /./d;g;q'
 # 獲取郵件地址。在上一個(gè)腳本所產(chǎn)生的那一行郵件頭的基礎(chǔ)上進(jìn)一步的將非電郵
 # 地址的部分剃除。（見(jiàn)上一腳本）
 sed 's/ *(.*)//; s/>.*//; s/.*[:<] *//'
 # 在每一行開(kāi)頭加上一個(gè)尖括號(hào)和空格（引用信息）
 sed 's/^/> /'
 # 將每一行開(kāi)頭處的尖括號(hào)和空格刪除（解除引用）
 sed 's/^> //'
 # 移除大部分的HTML標(biāo)簽（包括跨行標(biāo)簽）
 sed -e :a -e 's/<[^>]*>//g;/</N;//ba'

另外有需要云服務(wù)器可以了解下創(chuàng)新互聯(lián)scvps.cn，海內(nèi)外云服務(wù)器15元起步，三天無(wú)理由+7*72小時(shí)售后在線，公司持有idc許可證，提供“云服務(wù)器、裸金屬服務(wù)器、高防服務(wù)器、香港服務(wù)器、美國(guó)服務(wù)器、虛擬主機(jī)、免備案服務(wù)器”等云主機(jī)租用服務(wù)以及企業(yè)上云的綜合解決方案，具有“安全穩(wěn)定、簡(jiǎn)單易用、服務(wù)可用性高、性價(jià)比高”等特點(diǎn)與優(yōu)勢(shì)，專為企業(yè)上云打造定制，能夠滿足用戶豐富、多元化的應(yīng)用場(chǎng)景需求。

文章標(biāo)題：sed個(gè)人習(xí)慣用法總結(jié)-創(chuàng)新互聯(lián)
文章源于：http://chinadenli.net/article16/dgdcgg.html

成都網(wǎng)站建設(shè)公司_創(chuàng)新互聯(lián)，為您提供品牌網(wǎng)站制作、ChatGPT、小程序開(kāi)發(fā)、標(biāo)簽優(yōu)化、外貿(mào)網(wǎng)站建設(shè)、商城網(wǎng)站

廣告

聲明：本網(wǎng)站發(fā)布的內(nèi)容（圖片、視頻和文字）以用戶投稿、用戶轉(zhuǎn)載內(nèi)容為主，如果涉及侵權(quán)請(qǐng)盡快告知，我們將會(huì)在第一時(shí)間刪除。文章觀點(diǎn)不代表本網(wǎng)站立場(chǎng)，如需處理請(qǐng)聯(lián)系客服。電話：028-86922220；郵箱：631063699@qq.com。內(nèi)容未經(jīng)允許不得轉(zhuǎn)載，或轉(zhuǎn)載時(shí)需注明來(lái)源： 創(chuàng)新互聯(lián)